huh? what exactly are you trying to do? probably you need a fade tween.
shape tween means a shape transforming to another .... an image is a square, the other image is another square ... so at most there can be a square becoming a bigger or a lesser one, and then bump ... the second image appears.

ok, here you go: 2 layers, one for each image. Transform each image in a symbol (select image -> press F8 -> make it shape)

First image start from frame1.
in frame 15 for the first image, right click -> insert frame
then right click -> Create Motion Tween.
Again right click in frame 15 -> insert key frame.
click on the image in frame 15, go to Properties panel, select alpha from Color -> set alpha to 0.

Second image starts in frame 7.
same steps as for image 1, only the last keyframe will be in frame 22.
And in frame 22 -> Color set to none
In frame 7 -> Color -> alpha -> 0.

then test your movie.

Or, by actionscript (transform the images in movie clips. name their instances to mcImage and mcImage2):

import mx.transitions.Tween;
import mx.transitions.easing.*;

var tFadeOut:Tween  = new  Tween(mcImage, "_alpha", None.easeIn, 100 , 0, 20);
var tFadeIn:Tween  = new  Tween(mcImage2, "_alpha", None.easeOut, 0 , 100, 30);
stop();

for a given number of images ... N, when one image is half faded out the next image starts to fade in. For this you need to have the instance of all your images on the scene, also make sure all of them are alpha 0.

import mx.transitions.Tween;
import mx.transitions.easing.*;

function GetNextID(crtID, maxCount)
{
   crtID++;
   if (crtID >= maxCount)
   {
      crtID = 0;
   }
   return crtID;
}

function SetFade()
{
   mcFadeOutImg = this["mcImage"+crtImgID];
   crtImgID = GetNextID(crtImgID, maxImgCount);
   mcFadeInImg = this["mcImage"+crtImgID];
   trace(mcFadeOutImg+":in:"+mcFadeInImg);
   tFadeOut = new  Tween(mcFadeOutImg, "_alpha", None.easeOut, 100 , 0, 20);
   tFadeIn = new  Tween(mcFadeInImg, "_alpha", None.easeOut, 0 , 100, 20);
   tFadeIn.stop();

}
var tFadeOut:Tween;
var tFadeIn:Tween;
var crtImgID = 0;
var maxImgCount = 2;
var bFadeIn = false;
SetFade();

onEnterFrame = function()
{
   if (tFadeOut.position < 60 && !bFadeIn)
   {
      tFadeIn.start();
      bFadeIn = true;
   }
   if (tFadeIn.position == 100)
   {
      delete tFadeOut;
      delete tFadeIn;
      bFadeIn = false;
      SetFade();
   }
}
stop();